use fmt;
use sdl2;
use math;

export fn main() void = {
	sdl2::SDL_Init(sdl2::SDL_INIT_VIDEO)!;
	defer sdl2::SDL_Quit();

	const win = sdl2::SDL_CreateWindow("hi", sdl2::SDL_WINDOWPOS_UNDEFINED, sdl2::SDL_WINDOWPOS_UNDEFINED, 640, 480, sdl2::SDL_WindowFlags::NONE)!;
	defer sdl2::SDL_DestroyWindow(win);

	const wsurf = sdl2::SDL_GetWindowSurface(win)!;

	const xsurf = sdl2::SDL_CreateRGBSurface(0,
		512, 512, 32, 0xff0000, 0xff00, 0xff, 0)!;

	let dstate = drawing_state {
		drawing = false,
		pos = (0,0),
		picture = &picture_from_surface(xsurf)
	};

	let camera_pos: pos = (25, 50);

	clear_picture(dstate.picture, 0xffffff);
	outline_picture(dstate.picture);

	let quit = false;
	let n = 0;
	let lasttime = sdl2::SDL_GetTicks();
	for (!quit) {
		let ev = sdl2::event { ... };
		for (sdl2::SDL_PollEvent(&ev)! == 1) switch (ev.event_type) {
			case sdl2::SDL_EventType::QUIT => quit = true;
			case sdl2::SDL_EventType::KEYDOWN =>
				const keysym = ev.key.keysym.sym;
				if (keysym == sdl2::SDL_Keycode::ESCAPE) quit = true;
			case sdl2::SDL_EventType::MOUSEBUTTONDOWN,
					sdl2::SDL_EventType::MOUSEBUTTONUP =>
				const edata = ev.button;
				dstate.pos = (edata.x, edata.y);
				if (edata.button == 1)
					dstate.drawing = (edata.state == 1);
			case sdl2::SDL_EventType::MOUSEMOTION =>
				const edata = ev.motion;
				dstate.pos = (edata.x, edata.y);
			case => void;
		};

		movement(&camera_pos);

		do_drawing(&dstate);
		
		sdl2::SDL_BlitSurface(xsurf, null, wsurf, &sdl2::SDL_Rect {
			x = camera_pos.0, y = camera_pos.1, ...
		})!;

		sdl2::SDL_UpdateWindowSurface(win)!;
		n += 1;
		sdl2::SDL_Delay(1000/60);
	};
};

def SPEED = 17;
def DIAG_SPEED = 12;  // thereabouts

fn movement(pos: *pos) void = {
	const kb = sdl2::SDL_GetKeyboardState();
	let dx = 0;
	let dy = 0;
	if (kb[sdl2::SDL_Scancode::W]) dy -= 1;
	if (kb[sdl2::SDL_Scancode::S]) dy += 1;
	if (kb[sdl2::SDL_Scancode::A]) dx -= 1;
	if (kb[sdl2::SDL_Scancode::D]) dx += 1;

	let speed = SPEED;
	if (dx != 0 && dy != 0) speed = DIAG_SPEED;

	pos.0 += dx * speed;
	pos.1 += dy * speed;
};